Inverse d'elements d'un tableau

J'ai ce programme dont je ne sais pas où l'erreur:

Code:

program tab_claire;
uses wincrt;
type tab=array[1..10]of string;
var n:integer;
    p,q:tab;               
procedure taille(var nn:integer);
  begin
    repeat
      write('donner la taille');
      readln(nn);
    until nn in[1..10] ;
  end;
function verification(ch:string):boolean;
var i:integer;
    verif:boolean;
  begin
    i:=1;
    verif:=true;
    while(verif=true)and(i<=length(ch))do
        begin
        if not (ch[i] in ['0'..'9'])then
          verif:=false
        else
          i:=i+1;
        end;
    verification:=verif;
  end;

procedure saisie(nn:integer;var pp:tab);
var i:integer;
  begin
 
  for i:=1 to nn do
    repeat
      write('pp[',i,']=');
      readln(pp[i]);
    until verification(pp[i])=true;
  end;
 
function inverse(ch:string):string;
  var
  i,j:integer;
  ch1:string;
  cc: char;
  begin
    j:=1;
    ch1:='';
    for i:=length(ch) downto 1 do;
      begin
        ch1[j]:=ch[i];
        j:=j+1;
      end;
 
  inverse:=ch1;
  end;
procedure tableau_inverse(nn:integer; pp:tab ;var qq:tab);
  var i:integer;
  begin
    for i:=1 to nn do
    begin
      qq[i]:=inverse(pp[i]);
 
      end;
  end;
procedure affiche_tableau_inverse(nn:integer;qq:tab);
  var i:integer;
  begin
    for i:=1 to nn do
    writeln(qq[i]);
  end;
 begin
 taille(n);
 saisie(n,p);
 tableau_inverse(n,p,q);
 affiche_tableau_inverse(n,q);
 end.

Le programme fait:
- la saisie de nombre d'element dans un tableau
- la saisie des elements du tableau
- inverser chaque element du tableau et l'afficher (exemple : tableau initial (123|2345|987) on aura (321|5432|789) )
(RQ: c'est different du faite d'inverser le tableau ce qui donnera (987|2345|123))

Merci de m'aider
(c'est un exercice pascal niveau bac maths)

Il n'y a pas d'erreurs lors de la compilation? Juste une erreur de Logique, non?

methodiX a écrit:Il n'y a pas d'erreurs lors de la compilation? Juste une erreur de Logique, non?

Oui , pas d'erreur lors de la compilation, et meme coté logique je la vois pas où

Code:

function inverse(ch:string):string;
  var
  i,j:integer;
  ch1:string;
  cc: char;
  begin
    j:=1;
    ch1:='';
    for i:=length(ch) downto 1 do;
      begin
        ch1[j]:=ch[i];
        j:=j+1;
      end;
 
  inverse:=ch1;
  end;

Je n'ai pas le compilateur PASCAL maintenant, mais je crois que le problème est dans cette fonction qui fait l'inverse d'une String.
Plus précisément l'instruction suivante: ch1[j]:=ch[i];

Essaie de la remplacer par

Code:

ch1 := ch1 + ch[i]

et n'oublie pas d'initialiser ch à la chaine vide.

@+

J'ai déjà essayé de faire ainsi:

Code:

function inverse(ch:string):string;
  var
    i:integer;
    ch1:string;
    cc: char;
  begin
    ch1:='';
    for i:=length(ch) downto 1 do;
    begin
      ch1:=ch1+ch[i];
  end;

  inverse:=ch1;
end;

et ca donne ce reusltat:

Essaie de déclarer autrement le tableaux de String:

Code:

type tab=array[1..10]of string[30];

ça donne quoi?

J'ai pas compris comment declarer les chaines de caracteres comme des tableau, si déjà moi j'ai besoin d'une chaine(ch) pour avoir une autre qui soit son inverse, et que celle là (ch) est un element dans un tableau

Code:

string[30];

c'est pour dire qu'une String est composé uniquement de 30 caractères et non pas de 256 comme d'habitude.

Désoler de m'interposé, mais je n'ai pas compris à quoi sert ce programme ??

Gda.exe a écrit:Désoler de m'interposé, mais je n'ai pas compris à quoi sert ce programme ??

Relis attentivement l'énoncé de l'exercice.

Désoler...

J'aimerai savoir comment et où trouver un document expliquant d'avantage la programmation, parce que là, je ne comprend pas entièrement le code !

methodiX a écrit:

Code:

string[30];

c'est pour dire qu'une String est composé uniquement de 30 caractères et non pas de 256 comme d'habitude.

Ok.
Je vais essayer de faire ce que Nabil a proposé.

Gda.exe a écrit:Désoler...

J'aimerai savoir comment et où trouver un document expliquant d'avantage la programmation, parce que là, je ne comprend pas entièrement le code !

Y a une rubrique qui comporte des cours dans le language PASCAL pour comprendre ce code : https://infomath.1fr1.net/cours-pascal-f27/, vous pouvez commencer à avoir une idée à travers cette documentation fourni.
y a meme des exemples traités pour vous aider encore un peu pour comprendre.

Merci !!

Gda.exe a écrit:Merci !!

avec plaisir.

Voilà si j'ai bien compris j'ai fait ainsi:

Code:

function inverse(ch:string):string;
  var
  i,j:integer;
  type ch1=array[1..10]of string[30];
  begin
    j:=1;
    for i:=length(ch) downto 1 do;
      begin
        ch1[j]:=ch[i];
        j:=j+1;
      end;
 
    inverse:=ch1;
  end;

Mais j'ai une erreur de compilation au niveau de cette fonction.

Je sais pas si la syntaxe est correcte

C'est incorrect. Tu dois déclarer les types en haut du programme comme suit:

Code:

Program blabla;
uses wincrt;
type
  Tab = array[1..100] of string[30];


ca marche pas meme en declarant ainsi le type tab

je vais voir le soir !

voici ma proposition : (fonctionnelle)

Code:


program tab_claire;
// uses wincrt;
type tab=array [1..10] of string;
var n:integer;
    p,q:tab;             
procedure taille(var nn:integer);
  begin
    repeat
      write('donner la taille');
      readln(nn);
    until nn in[1..10] ;
  end;
 
function verification(ch:string):boolean;
var i:integer;
    verif:boolean;
  begin
    i:=1;
    verif:=true;
    while(verif=true)and(i<=length(ch))do
        begin
        if not (ch[i] in ['0'..'9'])then
          verif:=false
        else
          i:=i+1;
        end;
    verification:=verif;
  end;

procedure saisie(nn:integer;var pp:tab);
var i:integer;
  begin
  for i:=1 to nn do
    repeat
      write('pp[',i,']=');
      readln(pp[i]);
    until verification(pp[i]);
  end;
 
function inverse(ch:string):string;
  var
  i:integer;
  ch1:string;
begin
  ch1:='';
  for i:=1 to length(ch) do
    begin
      ch1:=ch[i]+ch1;
    end;
   
  inverse:=ch1;
end;
 
procedure tableau_inverse(nn:integer; pp:tab ;var qq:tab);
  var i:integer;
  begin
    for i:=1 to nn do
    begin
      qq[i]:=inverse(pp[i]);
      end;
  end;

procedure affiche_tableau_inverse(nn:integer;qq:tab);
  var i:integer;
  begin
    for i:=1 to nn do writeln(qq[i]);
  end;
 
 begin
  taille(n);
  saisie(n,p);
  tableau_inverse(n,p,q);
  affiche_tableau_inverse(n,q);
  readln;
 end.

Qu'est-ce qui a été modifié par rapport à la solution de début?

Merci Manianis.

Ce qui est modifié est le code de la fonction inverse.

mais je comprend pas la difference entre :

Code:


ch1:='',
for i:=length(ch) downto 1 do;
begin
  ch1:=ch1+ch[i];
end;

et:

Code:

 
ch1:='',
for i:=1 to length(ch) do
begin
  ch1:=ch[i]+ch1;
end;

Il faut faire attentions à l'usage abusif des points virgules.

for i:=length(ch) downto 1 do;

ne fait rien.

ah d'accord

merci bien manianis. Il faut faire attention!

AHHHH le probleme n'etait qu'un point virgule!!
J'ai déjà essayer cette solution avec le down to mais ca fonctionnait pas à cause de de point virgule!!! maintenant j'ai essayer encore une fois et ca fonctionne.

MERCI.